Spatial Media Metadataをインジェクトするバッチファイル

spatial-media/spatialmedia at master · google/spatial-media · GitHub

Pythonスクリプトがあるのでこれを使えば一括でメタデータを注入できます。

python3 spatialmedia -i input.mp4 output1.mp4

KDE neonではこれでPython3.6でも動きました。

あとはシェルスクリプトで処理すればよいのですが、やっぱりWindows10で動画変換することにしたので、Windows10でバッチ処理できるようにします。

Windows10にPython3をインストールする

Download Python | Python.org

ここからpython-3.7.3.exeをダウンロードしました。


Add Python 3.7 to PATHにチェックをつけてInstall Now。

32bit版を使っているのは単にダウンロードボタンをクリックするとそれがダウンロードされてきたからというだけです。


これでPython3のインストールが完了です。

Spatial Media Metadata Injectorのインストール

Releases · google/spatial-media · GitHub

次のここからSpatial Media Metadata Injector v2.1のSource code(zip)をダウンロードしました。

zipファイルをspatial-media-2.1という名前のフォルダに展開したらC:\Program Files2に移動させました。

複数のmp4ファイルに一括してインジェクトするバッチファイル

@echo off
rem Set the path to spatialmedia directrory.
set PKG_PATH="C:\Program Files2\spatial-media-2.1\spatialmedia"
setlocal enabledelayedexpansion
echo %~a1|find "d">NUL
if %ERRORLEVEL% EQU 0 (
  pushd %1
  set Count1=0
  for %%i in (*.mp4) do (
    set STR=%%~ni
    if not "!STR:~-9!"=="_injected" (
      echo.
      python %PKG_PATH% -i "%%~i" "%%~dpni_injected%%~xi"
      set /a Count1=Count1+1
    )
  )
  echo.
  echo Conversion of !Count1! files succeeded.
  echo.
  pause
) else (
  echo Please drop the folder containing mp4 files to be converted.
  echo.
  pause
)
endlocal
exit

metadatainjector.batという名前でこのバッチファイルを保存しました。

PKG_PATHにはspatialmediaディレクトリへのパスを指定しています。

このバッチファイルのショートカットをデスクトップに作成しました。

あとはメタデータを注入したいmp4ファイルが入ったフォルダをこのショートカットにドロップするとそのフォルダ内のmp4ファイルすべてにメタデータが注入されます。

_injected.mp4という名前で終わるファイルやサブフォルダのmp4ファイルには注入しません。

変換後のファイル名には_injectedを付けて保存します。

すでに同名ファイルがある場合は上書きします。